BNF Definition of Live Sequence Charts

<LSCSpec> ::= lscspec <ChartDefList> <InstVariList> end lscspec
<ChartDefList> ::= <ChartDef> ; <ChartDefList> | 

<ChartDef> ::= <ExtChartDef> | <UnvChartDef> 

<ExtChartDef> ::= extchart <LSCName> <InstDefList> end extchart
<UnvChartDef> ::= unvchart <LSCName> <PrechartDef> <InstDefList> end unvchart

<PrechartDef> ::= prechart <InstDefList> end prechart
<InstDefList> ::= <InstDef> ; <InstDefList> | 

<InstDef> ::= instance <InstName> <LocationDefList> end instance

<LocationDefList> ::= <LocationDef>; <LocationDefList> | 

<LocationDef> ::= hotlocation <HotLocationDef> end hotlocation | 
		coldlocation <ColdLocationDef> end coldlocation | 
		subchart <Subchart> end subchart

<HotLocationDef> ::= <EventDef> | <CoregionDef> | <ConditionDef>
<ColdLocationDef> ::= <EventDef> | <CoregionDef> | <ConditionDef>
<SubchartDef> ::= <LocationDefList>

<CoregionDef> ::= coregion <EventDefList> end coregion 
<EventDefList> ::= <EventDef> ; <EventDefList> | 
<ConditionDef> ::= hotcondition <Condition> end hotcondition |
		 coldcondition <Condition> end coldcondition

<EventDef> ::= <ActionDef> | <MessageDef> | <TimerEventDef>

<ActionDef> ::= action <Action> end action 
<MessageDef> ::= hotmessage <HotMessageDef> end hotmessage |
	       coldmessage <ColdMessageDef> end coldmessage 
<TimerEventDef> ::= <SetTimerDef> | <TimeOutDef> | <EndTimerDef>

<HotMessageDef> ::= <InputDef> | <OutputDef>
<ColdMessageDef> ::= <InputDef> | <OutputDef>

<SetTimerDef> ::= settimer <Clock> <Duration> end settimer
<TimeOutDef> ::= timeout <Clock> end timeout
<EndTimerDef> ::= endtimer <Clock> end endtimer

<InputDef> ::= input <Message> from <InstID> end input 
<OutputDef> ::= output <Message> to <InstID> end output
<InstID> ::= <InstName> | env

<InstVarList> ::= instvari <InstName> <VarList> endinstvari 
<VarList> ::= <VarDef> ; <VarList> | 
<VarDef> ::= vari <Variable> <TypeDef> end vari

<Action> ::= setstate Variable Value end setstate  

<Duration> ::= ... Some Real Number ...
<Clock> ::= ... Some Clock Name ...
<Condition> ::= ... Some Boolean Expression ...
<LSCName> ::= ... Some String Expression ...
<TypeDef> ::= ... Some Type Expression ...
<Variable> ::= ... Some String Expression ...
<Value> ::= ... Some Value Expression ...